Automating Restore Verify operations

USE [DBATasks]
GO
 
/****** Object:  Table [dbo].[Admin_BackupVerify]    Script Date: 7/19/2012 8:58:33 AM ******/
SET ANSI_NULLS ON
GO
 
SET QUOTED_IDENTIFIER ON
GO
 
SET ANSI_PADDING ON
GO
 
CREATE TABLE [dbo].[Admin_BackupVerify](
	[BackupRestoreID] [int] IDENTITY(1,1) NOT NULL,
	[ServerName] [varchar](50) NOT NULL,
	[DatabaseName] [varchar](50) NOT NULL,
	[LastCopied] [varchar](50) NOT NULL,
	[DateCreated] [datetime] NOT NULL,
	[LastRestorable] [varchar](50) NOT NULL,
	[DateRestored] [datetime] NOT NULL,
	[Verified] [bit] NOT NULL
) ON [PRIMARY]
 
GO
 
SET ANSI_PADDING OFF
GO
 
ALTER TABLE [dbo].[Admin_BackupVerify] ADD  CONSTRAINT [DF_Admin_BackupRestores_ServerName]  DEFAULT ('') FOR [ServerName]
GO
 
ALTER TABLE [dbo].[Admin_BackupVerify] ADD  CONSTRAINT [DF_Admin_BackupRestores_DatabaseName]  DEFAULT ('') FOR [DatabaseName]
GO
 
ALTER TABLE [dbo].[Admin_BackupVerify] ADD  CONSTRAINT [DF_Admin_BackupRestores_LastCopied]  DEFAULT ('') FOR [LastCopied]
GO
 
ALTER TABLE [dbo].[Admin_BackupVerify] ADD  CONSTRAINT [DF_Admin_BackupRestores_DateCreated]  DEFAULT (getdate()) FOR [DateCreated]
GO
 
ALTER TABLE [dbo].[Admin_BackupVerify] ADD  CONSTRAINT [DF_Admin_BackupRestores_Restored]  DEFAULT ('') FOR [LastRestorable]
GO
 
ALTER TABLE [dbo].[Admin_BackupVerify] ADD  CONSTRAINT [DF_Admin_BackupRestores_DateRestored]  DEFAULT ('1900-01-01') FOR [DateRestored]
GO
 
ALTER TABLE [dbo].[Admin_BackupVerify] ADD  CONSTRAINT [DF_Admin_BackupVerify_Verified]  DEFAULT ((0)) FOR [Verified]
GO

USE [DBATasks]
GO
 
/****** Object:  StoredProcedure [dbo].[Admin_RestoreVerifyOnly]    Script Date: 7/19/2012 8:20:20 AM ******/
SET ANSI_NULLS ON
GO
 
SET QUOTED_IDENTIFIER ON
GO
 
ALTER PROC [dbo].[Admin_RestoreVerifyOnly]
(
	@Path VARCHAR(200)
	, @ServerName VARCHAR(50)
)
 
AS
SET NOCOUNT ON;
/***************************************************************************
Author: Subhash Pant
Date Created: 07/17/2012
Date Modified:
Purpose: This process automatically finds the files
in the backup directory, and then runs the RESTORE VERIFYONLY
***************************************************************************/
 
DECLARE
	@DATE DATETIME ,
    @fileName NVARCHAR(75) ,
    @dir NVARCHAR(255) ,
    @loadPath NVARCHAR(500) ,
    @cmd1 NVARCHAR(330) ,
    @maxDate DATETIME ,
    @id INT ,
    @dateRestored DATETIME ,
    @restorePath NVARCHAR(500),   
    @lastRestored VARCHAR(50) ,
    @errMsg VARCHAR(500) ,
    @errSeverity INT ,
    @errState INT
/*********************************************************
Please configure these values
**********************************************************/
 
SET @loadPath = @Path
SET @restorePath = @Path
--SET @loadPath = '"K:\Backup\DB1"'
--SET @restorePath = 'K:\Backup\DB1'
 
/*********************************************************
No modification needed beyond this point
**********************************************************/
SET @dir = 'dir ' + @loadPath
SET @dateRestored = '1900-01-01'
 
IF OBJECT_ID('tempdb.dbo.#tmpDir') IS NULL
CREATE TABLE #tmpDir
(
	id INT IDENTITY ,
	ret NVARCHAR(1000)
)
ELSE
    TRUNCATE TABLE #tmpDir
 
INSERT #tmpDir
EXEC master.dbo.xp_cmdshell @dir
 
/*********************************************************
Remove unwanted values
**********************************************************/
DELETE #tmpDir
WHERE NOT ret LIKE '%.bak%'
OR ret IS NULL
 
 
IF EXISTS ( SELECT *
FROM #tmpDir AS tmp
LEFT OUTER JOIN DBATasks.dbo.Admin_BackupVerify AS lr 
	ON LTRIM(RTRIM(RIGHT(tmp.ret, CHARINDEX(' ', REVERSE(tmp.ret))))) = LastCopied
WHERE tmp.ret LIKE '%.bak%'
	AND LastCopied IS NULL )
 
BEGIN
    INSERT  DBATasks.dbo.Admin_BackupVerify(ServerName, DatabaseName, LastCopied, DateCreated)
    SELECT @ServerName,
			Left(LTRIM(RTRIM(RIGHT(tmp.ret,
				CHARINDEX(' ', REVERSE(tmp.ret))))), PatIndex('%[0-9]%', LTRIM(RTRIM(RIGHT(tmp.ret,
				CHARINDEX(' ', REVERSE(tmp.ret))))) + '1') - 1),
			LTRIM(RTRIM(RIGHT(tmp.ret,
				CHARINDEX(' ', REVERSE(tmp.ret))))) AS LastCopied,
            CASE WHEN tmp.ret LIKE '% PM %'
				THEN LEFT(tmp.ret, CHARINDEX(' PM ', tmp.ret) + 3)
            WHEN tmp.ret LIKE '% AM %'
				THEN LEFT(tmp.ret, CHARINDEX(' AM ', tmp.ret) + 3)
            END AS date_created
    FROM #tmpDir AS tmp
    LEFT OUTER JOIN DBATasks.dbo.Admin_BackupVerify AS lr 
	ON LTRIM(RTRIM(RIGHT(tmp.ret, CHARINDEX(' ', REVERSE(tmp.ret))))) = LastCopied
    WHERE tmp.ret LIKE '%.bak%'
		AND LastCopied IS NULL
END
 
WHILE EXISTS (SELECT *
              FROM DBATasks.dbo.Admin_BackupVerify
              WHERE [DateRestored] = '1900-01-01')
BEGIN
SELECT TOP 1
	@id = [BackupRestoreID] ,
	@lastRestored = [LastCopied] ,
	@cmd1 = 'RESTORE VERIFYONLY ' + 'from disk = '''
	+ @restorePath + '\' + [LastCopied] + ''''               
FROM DBATasks.dbo.Admin_BackupVerify
WHERE [DateRestored] = '1900-01-01'
ORDER BY [DateCreated]
 
BEGIN TRY
	--print @cmd1
	EXEC sp_executesql @cmd1
 
END TRY
BEGIN CATCH
	SELECT 
		@errMsg = ERROR_MESSAGE() ,
		@errSeverity = ERROR_SEVERITY() ,
		@errState = ERROR_STATE()
 
	RAISERROR(@errMsg, @errSeverity, @errState)
GOTO cleanup
END CATCH
	UPDATE [dbo].[Admin_BackupVerify] 
	SET 
		[LastRestorable] = @lastRestored,
		[DateRestored] = GETDATE(), 
		[Verified] = 1
 
	WHERE 
		[BackupRestoreID] = @id
END
cleanup:
SET NOCOUNT OFF;
GO